header {* Boolean Algebras *}
theory BooleanAlgebra
imports Main
begin
locale boolean =
fixes conj :: "'a => 'a => 'a" (infixr "\<sqinter>" 70)
fixes disj :: "'a => 'a => 'a" (infixr "\<squnion>" 65)
fixes compl :: "'a => 'a" ("∼ _" [81] 80)
fixes zero :: "'a" ("\<zero>")
fixes one :: "'a" ("\<one>")
assumes conj_assoc: "(x \<sqinter> y) \<sqinter> z = x \<sqinter> (y \<sqinter> z)"
assumes disj_assoc: "(x \<squnion> y) \<squnion> z = x \<squnion> (y \<squnion> z)"
assumes conj_commute: "x \<sqinter> y = y \<sqinter> x"
assumes disj_commute: "x \<squnion> y = y \<squnion> x"
assumes conj_disj_distrib: "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
assumes disj_conj_distrib: "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
assumes conj_one_right: "x \<sqinter> \<one> = x"
assumes disj_zero_right: "x \<squnion> \<zero> = x"
assumes conj_cancel_right: "x \<sqinter> ∼ x = \<zero>"
assumes disj_cancel_right: "x \<squnion> ∼ x = \<one>"
lemmas (in boolean) disj_ac =
disj_assoc disj_commute
mk_left_commute [of "disj", OF disj_assoc disj_commute]
lemmas (in boolean) conj_ac =
conj_assoc conj_commute
mk_left_commute [of "conj", OF conj_assoc conj_commute]
lemma (in boolean) dual: "boolean disj conj compl one zero"
apply (rule boolean.intro)
apply (rule disj_assoc)
apply (rule conj_assoc)
apply (rule disj_commute)
apply (rule conj_commute)
apply (rule disj_conj_distrib)
apply (rule conj_disj_distrib)
apply (rule disj_zero_right)
apply (rule conj_one_right)
apply (rule disj_cancel_right)
apply (rule conj_cancel_right)
done
text {* Complement *}
lemma (in boolean) complement_unique:
assumes 1: "a \<sqinter> x = \<zero>"
assumes 2: "a \<squnion> x = \<one>"
assumes 3: "a \<sqinter> y = \<zero>"
assumes 4: "a \<squnion> y = \<one>"
shows "x = y"
proof -
have "(a \<sqinter> x) \<squnion> (x \<sqinter> y) = (a \<sqinter> y) \<squnion> (x \<sqinter> y)" using 1 3 by simp
hence "(x \<sqinter> a) \<squnion> (x \<sqinter> y) = (y \<sqinter> a) \<squnion> (y \<sqinter> x)" using conj_commute by simp
hence "x \<sqinter> (a \<squnion> y) = y \<sqinter> (a \<squnion> x)" using conj_disj_distrib by simp
hence "x \<sqinter> \<one> = y \<sqinter> \<one>" using 2 4 by simp
thus "x = y" using conj_one_right by simp
qed
lemma (in boolean) compl_unique: "[|x \<sqinter> y = \<zero>; x \<squnion> y = \<one>|] ==> ∼ x = y"
by (rule complement_unique [OF conj_cancel_right disj_cancel_right])
lemma (in boolean) double_compl: "∼ (∼ x) = x"
proof (rule compl_unique)
from conj_cancel_right show "∼ x \<sqinter> x = \<zero>" by (simp add: conj_commute)
from disj_cancel_right show "∼ x \<squnion> x = \<one>" by (simp add: disj_commute)
qed
lemma (in boolean) compl_eq_compl_iff: "(∼ x = ∼ y) = (x = y)"
by (rule inj_eq [OF inj_on_inverseI], rule double_compl)
text {* Conjunction *}
lemma (in boolean) conj_absorb: "x \<sqinter> x = x"
proof -
have "x \<sqinter> x = (x \<sqinter> x) \<squnion> \<zero>" using disj_zero_right by simp
also have "… = (x \<sqinter> x) \<squnion> (x \<sqinter> ∼ x)" using conj_cancel_right by simp
also have "… = x \<sqinter> (x \<squnion> ∼ x)" using conj_disj_distrib by simp
also have "… = x \<sqinter> \<one>" using disj_cancel_right by simp
also have "… = x" using conj_one_right by simp
finally show ?thesis .
qed
lemma (in boolean) conj_zero_right: "x \<sqinter> \<zero> = \<zero>"
proof -
have "x \<sqinter> \<zero> = x \<sqinter> (x \<sqinter> ∼ x)" using conj_cancel_right by simp
also have "… = (x \<sqinter> x) \<sqinter> ∼ x" using conj_assoc by simp
also have "… = x \<sqinter> ∼ x" using conj_absorb by simp
also have "… = \<zero>" using conj_cancel_right by simp
finally show ?thesis .
qed
lemma (in boolean) compl_one: "∼ \<one> = \<zero>"
by (rule compl_unique [OF conj_zero_right disj_zero_right])
lemma (in boolean) conj_zero_left: "\<zero> \<sqinter> x = \<zero>"
by (subst conj_commute) (rule conj_zero_right)
lemma (in boolean) conj_one_left: "\<one> \<sqinter> x = x"
by (subst conj_commute) (rule conj_one_right)
lemma (in boolean) conj_cancel_left: "∼ x \<sqinter> x = \<zero>"
by (subst conj_commute) (rule conj_cancel_right)
lemma (in boolean) conj_left_absorb: "x \<sqinter> (x \<sqinter> y) = x \<sqinter> y"
by (simp add: conj_assoc [symmetric] conj_absorb)
lemma (in boolean) conj_disj_distrib2:
"(y \<squnion> z) \<sqinter> x = (y \<sqinter> x) \<squnion> (z \<sqinter> x)"
by (simp add: conj_commute conj_disj_distrib)
lemmas (in boolean) conj_disj_distribs =
conj_disj_distrib conj_disj_distrib2
text {* Disjunction *}
lemma (in boolean) disj_absorb: "x \<squnion> x = x"
by (rule boolean.conj_absorb [OF dual])
lemma (in boolean) disj_one_right: "x \<squnion> \<one> = \<one>"
by (rule boolean.conj_zero_right [OF dual])
lemma (in boolean) compl_zero: "∼ \<zero> = \<one>"
by (rule boolean.compl_one [OF dual])
lemma (in boolean) disj_zero_left: "\<zero> \<squnion> x = x"
by (rule boolean.conj_one_left [OF dual])
lemma (in boolean) disj_one_left: "\<one> \<squnion> x = \<one>"
by (rule boolean.conj_zero_left [OF dual])
lemma (in boolean) disj_cancel_left: "∼ x \<squnion> x = \<one>"
by (rule boolean.conj_cancel_left [OF dual])
lemma (in boolean) disj_left_absorb: "x \<squnion> (x \<squnion> y) = x \<squnion> y"
by (rule boolean.conj_left_absorb [OF dual])
lemma (in boolean) disj_conj_distrib2:
"(y \<sqinter> z) \<squnion> x = (y \<squnion> x) \<sqinter> (z \<squnion> x)"
by (rule boolean.conj_disj_distrib2 [OF dual])
lemmas (in boolean) disj_conj_distribs =
disj_conj_distrib disj_conj_distrib2
text {* De Morgan's Laws *}
lemma (in boolean) de_Morgan_conj: "∼ (x \<sqinter> y) = ∼ x \<squnion> ∼ y"
proof (rule compl_unique)
have "(x \<sqinter> y) \<sqinter> (∼ x \<squnion> ∼ y) = ((x \<sqinter> y) \<sqinter> ∼ x) \<squnion> ((x \<sqinter> y) \<sqinter> ∼ y)"
by (rule conj_disj_distrib)
also have "… = (y \<sqinter> (x \<sqinter> ∼ x)) \<squnion> (x \<sqinter> (y \<sqinter> ∼ y))"
by (simp add: conj_ac)
finally show "(x \<sqinter> y) \<sqinter> (∼ x \<squnion> ∼ y) = \<zero>"
by (simp add: conj_cancel_right conj_zero_right disj_zero_right)
next
have "(x \<sqinter> y) \<squnion> (∼ x \<squnion> ∼ y) = (x \<squnion> (∼ x \<squnion> ∼ y)) \<sqinter> (y \<squnion> (∼ x \<squnion> ∼ y))"
by (rule disj_conj_distrib2)
also have "… = (∼ y \<squnion> (x \<squnion> ∼ x)) \<sqinter> (∼ x \<squnion> (y \<squnion> ∼ y))"
by (simp add: disj_ac)
finally show "(x \<sqinter> y) \<squnion> (∼ x \<squnion> ∼ y) = \<one>"
by (simp add: disj_cancel_right disj_one_right conj_one_right)
qed
lemma (in boolean) de_Morgan_disj: "∼ (x \<squnion> y) = ∼ x \<sqinter> ∼ y"
by (rule boolean.de_Morgan_conj [OF dual])
text {* Symmetric Difference *}
locale boolean_xor = boolean +
fixes xor :: "'a => 'a => 'a" (infixr "⊕" 65)
assumes xor_def: "x ⊕ y = (x \<sqinter> ∼ y) \<squnion> (∼ x \<sqinter> y)"
lemma (in boolean_xor) xor_def2:
"x ⊕ y = (x \<squnion> y) \<sqinter> (∼ x \<squnion> ∼ y)"
by (simp add: xor_def conj_disj_distribs
disj_ac conj_ac conj_cancel_right disj_zero_left)
lemma (in boolean_xor) xor_commute: "x ⊕ y = y ⊕ x"
by (simp add: xor_def conj_commute disj_commute)
lemma (in boolean_xor) xor_assoc: "(x ⊕ y) ⊕ z = x ⊕ (y ⊕ z)"
proof -
let ?t = "(x \<sqinter> y \<sqinter> z) \<squnion> (x \<sqinter> ∼ y \<sqinter> ∼ z) \<squnion>
(∼ x \<sqinter> y \<sqinter> ∼ z) \<squnion> (∼ x \<sqinter> ∼ y \<sqinter> z)"
have "?t \<squnion> (z \<sqinter> x \<sqinter> ∼ x) \<squnion> (z \<sqinter> y \<sqinter> ∼ y) =
?t \<squnion> (x \<sqinter> y \<sqinter> ∼ y) \<squnion> (x \<sqinter> z \<sqinter> ∼ z)"
by (simp add: conj_cancel_right conj_zero_right)
thus "(x ⊕ y) ⊕ z = x ⊕ (y ⊕ z)"
apply (simp add: xor_def de_Morgan_disj de_Morgan_conj double_compl)
apply (simp add: conj_disj_distribs conj_ac disj_ac)
done
qed
lemmas (in boolean_xor) xor_ac =
xor_assoc xor_commute
mk_left_commute [of "xor", OF xor_assoc xor_commute]
lemma (in boolean_xor) xor_zero_right: "x ⊕ \<zero> = x"
by (simp add: xor_def compl_zero conj_one_right conj_zero_right disj_zero_right)
lemma (in boolean_xor) xor_zero_left: "\<zero> ⊕ x = x"
by (subst xor_commute) (rule xor_zero_right)
lemma (in boolean_xor) xor_one_right: "x ⊕ \<one> = ∼ x"
by (simp add: xor_def compl_one conj_zero_right conj_one_right disj_zero_left)
lemma (in boolean_xor) xor_one_left: "\<one> ⊕ x = ∼ x"
by (subst xor_commute) (rule xor_one_right)
lemma (in boolean_xor) xor_self: "x ⊕ x = \<zero>"
by (simp add: xor_def conj_cancel_right conj_cancel_left disj_zero_right)
lemma (in boolean_xor) xor_left_self: "x ⊕ (x ⊕ y) = y"
by (simp add: xor_assoc [symmetric] xor_self xor_zero_left)
lemma (in boolean_xor) xor_compl_left: "∼ x ⊕ y = ∼ (x ⊕ y)"
apply (simp add: xor_def de_Morgan_disj de_Morgan_conj double_compl)
apply (simp add: conj_disj_distribs)
apply (simp add: conj_cancel_right conj_cancel_left)
apply (simp add: disj_zero_left disj_zero_right)
apply (simp add: disj_ac conj_ac)
done
lemma (in boolean_xor) xor_compl_right: "x ⊕ ∼ y = ∼ (x ⊕ y)"
apply (simp add: xor_def de_Morgan_disj de_Morgan_conj double_compl)
apply (simp add: conj_disj_distribs)
apply (simp add: conj_cancel_right conj_cancel_left)
apply (simp add: disj_zero_left disj_zero_right)
apply (simp add: disj_ac conj_ac)
done
lemma (in boolean_xor) xor_cancel_right: "x ⊕ ∼ x = \<one>"
by (simp add: xor_compl_right xor_self compl_zero)
lemma (in boolean_xor) xor_cancel_left: "∼ x ⊕ x = \<one>"
by (subst xor_commute) (rule xor_cancel_right)
lemma (in boolean_xor) conj_xor_distrib: "x \<sqinter> (y ⊕ z) = (x \<sqinter> y) ⊕ (x \<sqinter> z)"
proof -
have "(x \<sqinter> y \<sqinter> ∼ z) \<squnion> (x \<sqinter> ∼ y \<sqinter> z) =
(y \<sqinter> x \<sqinter> ∼ x) \<squnion> (z \<sqinter> x \<sqinter> ∼ x) \<squnion> (x \<sqinter> y \<sqinter> ∼ z) \<squnion> (x \<sqinter> ∼ y \<sqinter> z)"
by (simp add: conj_cancel_right conj_zero_right disj_zero_left)
thus "x \<sqinter> (y ⊕ z) = (x \<sqinter> y) ⊕ (x \<sqinter> z)"
by (simp (no_asm_use) add:
xor_def de_Morgan_disj de_Morgan_conj double_compl
conj_disj_distribs conj_ac disj_ac)
qed
lemma (in boolean_xor) conj_xor_distrib2:
"(y ⊕ z) \<sqinter> x = (y \<sqinter> x) ⊕ (z \<sqinter> x)"
proof -
have "x \<sqinter> (y ⊕ z) = (x \<sqinter> y) ⊕ (x \<sqinter> z)"
by (rule conj_xor_distrib)
thus "(y ⊕ z) \<sqinter> x = (y \<sqinter> x) ⊕ (z \<sqinter> x)"
by (simp add: conj_commute)
qed
lemmas (in boolean_xor) conj_xor_distribs =
conj_xor_distrib conj_xor_distrib2
end
lemma disj_ac:
disj (disj x y) z = disj x (disj y z) [.]
disj x y = disj y x [.]
disj x (disj y z) = disj y (disj x z) [.]
lemma conj_ac:
conj (conj x y) z = conj x (conj y z) [.]
conj x y = conj y x [.]
conj x (conj y z) = conj y (conj x z) [.]
lemma dual:
boolean disj conj compl one zero [.]
lemma complement_unique:
[| conj a x = zero; disj a x = one; conj a y = zero; disj a y = one |] ==> x = y [.]
lemma compl_unique:
[| conj x y = zero; disj x y = one |] ==> compl x = y [.]
lemma double_compl:
compl (compl x) = x [.]
lemma compl_eq_compl_iff:
(compl x = compl y) = (x = y) [.]
lemma conj_absorb:
conj x x = x [.]
lemma conj_zero_right:
conj x zero = zero [.]
lemma compl_one:
compl one = zero [.]
lemma conj_zero_left:
conj zero x = zero [.]
lemma conj_one_left:
conj one x = x [.]
lemma conj_cancel_left:
conj (compl x) x = zero [.]
lemma conj_left_absorb:
conj x (conj x y) = conj x y [.]
lemma conj_disj_distrib2:
conj (disj y z) x = disj (conj y x) (conj z x) [.]
lemma conj_disj_distribs:
conj x (disj y z) = disj (conj x y) (conj x z) [.]
conj (disj y z) x = disj (conj y x) (conj z x) [.]
lemma disj_absorb:
disj x x = x [.]
lemma disj_one_right:
disj x one = one [.]
lemma compl_zero:
compl zero = one [.]
lemma disj_zero_left:
disj zero x = x [.]
lemma disj_one_left:
disj one x = one [.]
lemma disj_cancel_left:
disj (compl x) x = one [.]
lemma disj_left_absorb:
disj x (disj x y) = disj x y [.]
lemma disj_conj_distrib2:
disj (conj y z) x = conj (disj y x) (disj z x) [.]
lemma disj_conj_distribs:
disj x (conj y z) = conj (disj x y) (disj x z) [.]
disj (conj y z) x = conj (disj y x) (disj z x) [.]
lemma de_Morgan_conj:
compl (conj x y) = disj (compl x) (compl y) [.]
lemma de_Morgan_disj:
compl (disj x y) = conj (compl x) (compl y) [.]
lemma xor_def2:
xor x y = conj (disj x y) (disj (compl x) (compl y)) [.]
lemma xor_commute:
xor x y = xor y x [.]
lemma xor_assoc:
xor (xor x y) z = xor x (xor y z) [.]
lemma xor_ac:
xor (xor x y) z = xor x (xor y z) [.]
xor x y = xor y x [.]
xor x (xor y z) = xor y (xor x z) [.]
lemma xor_zero_right:
xor x zero = x [.]
lemma xor_zero_left:
xor zero x = x [.]
lemma xor_one_right:
xor x one = compl x [.]
lemma xor_one_left:
xor one x = compl x [.]
lemma xor_self:
xor x x = zero [.]
lemma xor_left_self:
xor x (xor x y) = y [.]
lemma xor_compl_left:
xor (compl x) y = compl (xor x y) [.]
lemma xor_compl_right:
xor x (compl y) = compl (xor x y) [.]
lemma xor_cancel_right:
xor x (compl x) = one [.]
lemma xor_cancel_left:
xor (compl x) x = one [.]
lemma conj_xor_distrib:
conj x (xor y z) = xor (conj x y) (conj x z) [.]
lemma conj_xor_distrib2:
conj (xor y z) x = xor (conj y x) (conj z x) [.]
lemma conj_xor_distribs:
conj x (xor y z) = xor (conj x y) (conj x z) [.]
conj (xor y z) x = xor (conj y x) (conj z x) [.]